原因：电脑或者U盘中毒所致
解决方案如下：代码是网上大神缩写哈，非本人。
批量文件夹单个恢复均适用，快捷的批量取消和设置隐藏属性和系统属性，真是佩服那位大神，o(≧v≦)o~~好棒，对大神标表示感谢。
步骤：
1.右键新建一个txt文本文档。
2.将后面提供的代码复制粘贴到新建的txt文本文档内并保存。
3.将该文本文档后缀名.txt改为.bat，即该文档变成了批处理文件/批处理脚本
4.不是双击该批处理文件使用，而是将需要恢复的文件夹或文件拉到该批处理文件上，如图：
将工作区这个文件拉到改成.bat后缀的原文本文档图标上，
之后显示：
之后步骤一直选“2 去掉”项，然后“Enter”确定即可。要是要恢复整个U盘的文件夹，可直接将U盘那盘符拉到.bat那文件上，同原来一样操作。
以下为需要保存到新建文本文档的代码：
@echo off&setlocal enableextensions enabledelayedexpansion
title 修改系统文件属性和隐藏文件属性
if "%~1"=="" (echo 你没有拖入 任何磁盘或文件或文件夹
echo 请把 要处理的磁盘或文件或文件夹 拖到 批处理文件图标
echo 不要 双击启动 批处理&pause&goto :eof)
call:choose "设置隐藏文件属性,请选择:" 不改变 去掉 设置
(set h=)&(if !c! equ 2 set h=-)&(if !c! equ 3 set h=+)
call:choose "设置系统文件属性,请选择:" 不改变 去掉 设置
(set s=)&(if !c! equ 2 set s=-)&(if !c! equ 3 set s=+)
call:choose "设置应用范围,请选择:" 文件或文件夹自身属性及第一级目录内容属性 文件夹第一级目录内容属性
for %%i in (%*) do (if !c! equ 1 call:attrib "%%~i"
for /f "delims=" %%j in ('dir /a /b "%%~i"') do call:attrib "%%~i\%%~j")
pause&goto :eof
:choose
(set c=)&(set n=)&for %%i in (%*) do echo !n! %%~i&set /a n+=1
(set /p c=)&(set /a c=c)&if !c! geq 0 if !c! leq !n! echo.&goto :eof
goto choose
:attrib
setlocal&(set a=)&(set a=%~a1)&if "!a!"=="" goto :eof
if not defined h if "!a:~3,1!"=="h" (set h=+) else (set h=-)
if not defined s if "!a:~4,1!"=="s" (set s=+) else (set s=-)
echo 正在处理: %~1&attrib !h!h !s!s "%~1"&goto :eof
